Bookmarks2opera.xsl

From Aventine Solutions

<?xml version="1.0" encoding="UTF-8" ?>
<!-- $Id: bookmarks2opera.xsl,v 1.1 2004/04/15 12:48:19 matthew Exp $ -->
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">
  <xsl:output method="text"/>
  <xsl:template match="bookmarks">
    <xsl:text xml:space="preserve">Opera Hotlist version 2.0
Options: encoding = utf8, version=3

#FOLDER
</xsl:text>
    <xsl:value-of select="concat( '  NAME=*** imported *** ', @repository )"/>
    <xsl:apply-templates/>
    <xsl:text xml:space="preserve">
-</xsl:text>
  </xsl:template>
  <xsl:template match="list">
    <xsl:text xml:space="preserve">
#FOLDER
</xsl:text>
    <xsl:value-of select="concat( '  NAME=', @heading )"/>
    <xsl:if test="matches( @operaPersonalBar, '^[YyTtJj]' )">
  ON PERSONALBAR=YES
  PERSONALBAR_POS=1
    </xsl:if>
    <xsl:apply-templates/>
    <xsl:text xml:space="preserve">
-</xsl:text>
  </xsl:template>
  <xsl:template match="link">
    <xsl:text xml:space="preserve">
#URL
</xsl:text>
    <xsl:value-of select="concat( '  NAME=', normalize-space( . ) )"/>
    <xsl:text xml:space="preserve">
</xsl:text>
    <xsl:value-of select="concat( '  URL=', @href )"/>
    <xsl:if test="matches( @operaPersonalBar, '^[YyTtJj]' )">
  ON PERSONALBAR=YES
  PERSONALBAR_POS=1
    </xsl:if>
  </xsl:template>
</xsl:stylesheet>
<!-- EOF: $RCSfile: bookmarks2opera.xsl,v $ -->